RealView Compilation Tools Assembler Guide: 4.4.2. ADD, SUB, RSB, ADC, SBC, and RSC

4.4.2. ADD, SUB, RSB, ADC, SBC, and RSC

Add, Subtract, and Reverse Subtract, each with or without Carry.

Syntax

op{S}{cond} {Rd}, Rn, Operand2
op{cond} {Rd}, Rn, #imm12               ; Thumb-2 only

where:

op

is one of:

ADD: Add.
ADC: Add with Carry.
SUB: Subtract.
RSB: Reverse Subtract.
SBC: Subtract with Carry.
RSC: Reverse Subtract with Carry (ARM only).

S

is an optional suffix. If S is specified, the condition code flags are updated on the result of the operation (see Conditional execution).

cond

is an optional condition code (see Conditional execution).

Rd

is the destination register.

Rn

is the register holding the first operand.

Operand2

is a flexible second operand. See Flexible second operand for details of the option.

imm12

is any value in the range 0-4095. Only permitted for ADD and SUB instructions, and only in Thumb-2 code.

Usage

The ADD instruction adds the values in Rn and Operand2.

The SUB instruction subtracts the value of Operand2 from the value in Rn.

The RSB (Reverse Subtract) instruction subtracts the value in Rn from the value of Operand2. This is useful because of the wide range of options for Operand2.

You can use ADC, SBC, and RSC to synthesize multiword arithmetic (see Multiword arithmetic examples).

The ADC (Add with Carry) instruction adds the values in Rn and Operand2, together with the carry flag.

The SBC (Subtract with Carry) instruction subtracts the value of Operand2 from the value in Rn. If the carry flag is clear, the result is reduced by one.

The RSC (Reverse Subtract with Carry) instruction subtracts the value in Rn from the value of Operand2. If the carry flag is clear, the result is reduced by one.

In certain circumstances, the assembler can substitute one instruction for another. Be aware of this when reading disassembly listings. See Instruction substitution for details.

Use of r15 in Thumb-2 instructions

In most of these instructions, you cannot use r15 for Rd, or any operand.

The exception is that you can use r15 for Rn in ADD and SUB instructions, with a constant Operand2 value in the range 0-4095, and no S suffix. These instructions are useful for generating pc-relative addresses. Bit[1] of the pc value reads as 0 in this case, so that the base address for the calculation is always word-aligned.

Use of r15 in ARM instructions

If you use r15 as Rn, the value used is the address of the instruction plus 8.

If you use r15 as Rd:

Execution branches to the address corresponding to the result.
If you use the S suffix, the SPSR of the current mode is copied to the CPSR. You can use this to return from exceptions (see Chapter 6 Handling Processor Exceptions in the RealView Compilation Tools Developer Guide).

Caution

Do not use the S suffix when using r15 as Rd in User mode or System mode. The effect of such an instruction is unpredictable, but the assembler cannot warn you at assembly time.

You cannot use r15 for Rd or any operand in any data processing instruction that has a register-controlled shift (see Flexible second operand).

Condition flags

If S is specified, these instructions update the N, Z, C and V flags according to the result.

16-bit instructions

The following forms of these instructions are available in Thumb code, and are 16-bit instructions when used in Thumb-2 code:

ADDS Rd, Rn, #imm: imm range 0-7. Rd and Rn must both be Lo registers.
ADDS Rd, Rn, Rm: Rd, Rn and Rm must all be Lo registers.
ADD Rd, Rd, Rm: ARMv6 and earlier: either Rd or Rm, or both, must be a Hi register. ARMv6T2 and above: this restriction does not apply.
ADDS Rd, Rd, #imm: imm range 0-255. Rd must be a Lo register.
ADCS Rd, Rd, Rm: Rd, Rn and Rm must all be Lo registers.
ADD SP, SP, #imm: imm range 0-508, word aligned.
ADD Rd, SP, #imm: imm range 0-1020, word aligned. Rd must be a Lo register.
ADD Rd, pc, #imm: imm range 0-1020, word aligned. Rd must be a Lo register. Bits[1:0] of the pc are read as 0 in this instruction.
SUBS Rd, Rn, Rm: Rd, Rn and Rm must all be Lo registers.
SUBS Rd, Rn, #imm: imm range 0-7. Rd and Rn both Lo registers.
SUBS Rd, Rd, #imm: imm range 0-255. Rd must be a Lo register.
SBCS Rd, Rd, Rm: Rd, Rn and Rm must all be Lo registers.
SUB SP, SP, #imm: imm range 0-508, word aligned.
RSBS Rd, Rn, #0: Rd and Rn both Lo registers.

Examples

    ADD     r2, r1, r3
    SUBS    r8, r6, #240        ; sets the flags on the result
    RSB     r4, r4, #1280       ; subtracts contents of r4 from 1280
    ADCHI   r11, r0, r3         ; only executed if C flag set and Z
                                ; flag clear
    RSCSLE  r0,r5,r0,LSL r4     ; conditional, flags set

Incorrect example

    RSCSLE  r0,r15,r0,LSL r4    ; r15 not permitted with register
                                ; controlled shift

Multiword arithmetic examples

These two instructions add a 64-bit integer contained in r2 and r3 to another 64-bit integer contained in r0 and r1, and place the result in r4 and r5.

    ADDS    r4, r0, r2    ; adding the least significant words
    ADC     r5, r1, r3    ; adding the most significant words

These instructions subtract one 96-bit integer from another:

    SUBS    r3, r6, r9
    SBCS    r4, r7, r10
    SBC     r5, r8, r11

For clarity, the above examples use consecutive registers for multiword values. There is no requirement to do this. The following, for example, is perfectly valid:

    SUBS    r6, r6, r9
    SBCS    r9, r2, r1
    SBC     r2, r8, r11

Copyright © 2002-2007 ARM Limited. All rights reserved.	ARM DUI 0204H
Non-Confidential
PDF version