## 5.8 Example showing the benefits of using conditional instructions

Using conditional instructions rather than conditional branches can save both code size and cycles.

This topic illustrates the difference between using branches and using conditional instructions. It uses the Euclid algorithm for the Greatest Common Divisor (gcd) to demonstrate how conditional instructions improve code size and speed.
In C the gcd algorithm can be expressed as:
```int gcd(int a, int b)
{
while (a != b)
{
if (a > b)
a = a - b;
else
b = b - a;
}
return a;
}```
The following examples show implementations of the gcd algorithm with and without conditional instructions:

### Note

The detailed analysis of execution speed only applies to an ARM7™ processor. The code density calculations apply to all ARM processors.

## Example of conditional execution using branches in ARM code

This is an ARM code implementation of the gcd algorithm using branches, without using any other conditional instructions. Conditional execution is achieved by using conditional branches, rather than individual conditional instructions:
```gcd     CMP      r0, r1
BEQ      end
BLT      less
SUBS     r0, r0, r1  ; could be SUB r0, r0, r1 for ARM
B        gcd
less
SUBS     r1, r1, r0  ; could be SUB r1, r1, r0 for ARM
B        gcd
end```
The code is seven instructions long because of the number of branches. Every time a branch is taken, the processor must refill the pipeline and continue from the new location. The other instructions and non-executed branches use a single cycle each.
The following table shows the number of cycles this implementation uses on an ARM7 processor when R0 equals 1 and R1 equals 2:

Table 5-3 Conditional branches only

R0: a R1: b Instruction Cycles (ARM7)
1 2 `CMP r0, r1` 1
1 2 `BEQ end` 1 (not executed)
1 2 `BLT less` 3
1 2 `SUB r1, r1, r0` 1
1 2 `B gcd` 3
1 1 `CMP r0, r1` 1
1 1 `BEQ end` 3
Total = 13

## Example of conditional execution using conditional instructions in ARM code

This is an ARM code implementation of the gcd algorithm using individual conditional instructions in ARM code. The gcd algorithm only takes four instructions:
```gcd
CMP      r0, r1
SUBGT    r0, r0, r1
SUBLE    r1, r1, r0
BNE      gcd```
In addition to improving code size, in most cases this code executes faster than the version that uses only branches.
The following table shows the number of cycles this implementation uses on an ARM7 processor when R0 equals 1 and R1 equals 2:

Table 5-4 All instructions conditional

R0: a R1: b Instruction Cycles (ARM7)
1 2 `CMP r0, r1` 1
1 2 `SUBGT r0,r0,r1` 1 (not executed)
1 1 `SUBLT r1,r1,r0` 1
1 1 `BNE gcd` 3
1 1 `CMP r0,r1` 1
1 1 `SUBGT r0,r0,r1` 1 (not executed)
1 1 `SUBLT r1,r1,r0` 1 (not executed)
1 1 `BNE gcd` 1 (not executed)
Total = 10
Comparing this with the example that uses only branches:
• Replacing branches with conditional execution of all instructions saves three cycles.
• Where R0 equals R1, both implementations execute in the same number of cycles. For all other cases, the implementation that uses conditional instructions executes in fewer cycles than the implementation that uses branches only.

## Example of conditional execution using conditional instructions in Thumb code

In ARMv6T2 and later architectures, you can use the `IT` instruction to write conditional instructions in Thumb code. The Thumb code implementation of the gcd algorithm using conditional instructions is very similar to the implementation in ARM code. The implementation in Thumb code is:
```gcd
CMP     r0, r1
ITE     GT
SUBGT   r0, r0, r1
SUBLE   r1, r1, r0
BNE     gcd```
This assembles equally well to ARM or Thumb code. The assembler checks the `IT` instructions, but omits them on assembly to ARM code.
It requires one more instruction in Thumb code (the `IT` instruction) than in ARM code, but the overall code size is 10 bytes in Thumb code compared with 16 bytes in ARM code.

## Example of conditional execution code using branches in Thumb code

In architectures before ARMv6T2, there is no `IT` instruction and therefore Thumb instructions cannot be executed conditionally except for the `B` branch instruction. The gcd algorithm must be written with conditional branches and is very similar to the ARM code implementation using branches, without conditional instructions.
The Thumb code implementation of the gcd algorithm without conditional instructions requires seven instructions. The overall code size is 14 bytes. This is even less than the ARM implementation that uses conditional instructions, which uses 16 bytes.
In addition, on a system using 16-bit memory, this Thumb implementation runs faster than both ARM implementations because only one memory access is required for each 16-bit Thumb instruction, whereas each 32-bit ARM instruction requires two fetches.
##### Related concepts
5.7 Benefits of using conditional execution
5.9 Optimization for execution speed
##### Related reference
10.39 IT
5.5 Condition code suffixes and related flags
##### Related information
ARM Architecture Reference Manual